HTBasic作業Windowの設定

Tip

　■ HTBasic グラフィックススクリーンでの設定 ■

HTBasic グラフィックススクリーンでの設定

HTBasic for Windows (Rocky Mountaine Basic 仕様のBASIC)でのグラフィック表示/描画は、単純化されたグラフィック・マッピング(Simplified Graphics Mapping)に従い行います。

構造と用語

フィジカル・スクリーン

hard clip limit :　ハードクリップ・リミット
	現在のPLOTTER IS 装置における、ハードウェア上の表示限界(最大値又はページサイズ) 。ディスプレイ装置において、HTBasic for Windowsでのハードクリップ・リミットは、子ウィンドゥ(Child Window)の表示域となります。
GDUs (Graphic Display Units) :　グラフィク・ディスプレイ・ユニット
	GDUは、グラフィック出力装置上の表示領域の物理的な境界に対する単位です。 GDUはグラフィック出力装置の短い方の 1/100と定義します。
RATIO :　レシオ
	現在のPLOTTER IS 装置の X方向のハードクリップ・リミットと Y方向のハードクリップ・リミットの比率。　短い辺は 100 GDU、長い方の辺は 100*RATIO GDUの長さとなります。
0,0 :　原点
	ハードクリップ・リミット内の原点で、長軸がX軸、短軸がY軸となり、左端の最下端が 0,0 、右端の最上端が 100*RATIO,100 となります。単位はGDU。
VIEWPORT :　ビューポート
	VIEWPORTの設定には、VIEWPORTステートメントを使用します。 VIEWPORTステートメントは、グラフィック出力で使用されるディプレイまたはプロッター等の装置上での表示領域を、VIEWPORT境界並びにソフトクリップ・リミットの境界を設定します。　単位はGDU。
physical pen image :　フィジカル・ペンで定義された属性で描かれる画像
	VIEWPORTへの描画は、TBasic for Windows physical penとして、PEN番号とCOLORとred/green/blueの組み合わせによる色を使用して行います。

ロジカル・スクリーン

WINDOW :　ウィンドゥ
	WINDOWは、WINDOWステートメントでグラフィックスデータの表示可能な境界を、ユーザが定義する単位で設定します。 UDU単位。 WINDOWでは、物理的表示域であるVIEWPORTを、 UDU単位でロジカルに表示します。
UDU（User Defined Graphic Units） :　ユーザ・デファインド・グラフィック単位
	WINDOWステートメントで、X軸で表示するmax/min並びにY軸で表示するmax/minの値をユーザのユーザが定義する単位で設定します。 X軸で表示される長さは Xmax-Xmin UDU、Y軸で表示される長さは Ymax-Ymin UDUとなります。
logical pen image :　ロジカル・ペンで定義された属性で描かれる画像
	WINDOWへの描画は、TBasic for Windows logical penとして、PEN番号を指定して行います。表示される色は、HTBasic for Windowsが動作しているPCのサポートするカラー数で決まります。
soft clip limits :　ソフトクリップ・リミット　(注）付記
	WINDOWから、外側への描画は CLIPステートメントを使用して可能になリます。CLIPステートメントの実行前のソフトクリップ・リミットはVIEWPOT表示域(ハードクリップ・リミット)と同じです。CLIPステートメントの実行後の単位は、VIEWPORTの単位では無く、WINDOW(またはSHOW)で設定された単位が使用されます。 CLIP OFF ステートメントを実行するとソフトクリップ・リミットをハードクリップ・リミットに戻します。

例） Graphics 機能テスト

1 ! Graphics Test
2 ! - Main -
3 !
10 PEN 1
11 X_left=-2
12 X_right=15
13 Y_bottom=-2
14 Y_top=2
15 X_tick=1
16 Y_tick=1
20 !
21 !
30 VIEWPORT 10,50,50,80 !#1
31 GOSUB Frame1
32 VIEWPORT 60,100,50,80 !#2
33 GOSUB Frame1
34 VIEWPORT 10,100,15,40 !#3
35 GOSUB Frame1
40 !
41 STOP

180 ! - Sub FRAME -
190 Frame1: FRAME
200 WINDOW X_left,X_right,Y_bottom,Y_top
210 AXES X_tick,Y_tick,0,0,10,3,3
220 MOVE 10,Y_top
230 DRAW 10,Y_bottom
240 LORG 3
250 MOVE X_left,Y_top
260 CSIZE 1
270 LABEL "VIEW PORT"
280 Flg=1

290 FOR I=-2 TO 100 STEP .1
300 IF Flg=1 THEN
310 PLOT I,SIN(I),2
320 ELSE
330 Flg=0
340 END IF
350 PLOT I,SIN(I)
360 NEXT I
370 CSIZE 1
380 LORG 1
390 FOR Loop=X_left TO X_right STEP X_tick
400 MOVE Loop,0
410 LABEL Loop
420 NEXT Loop
430 LORG 7
440 FOR Loop=Y_bottom TO Y_top STEP Y_tick
450 MOVE 0,Loop
460 LABEL Loop
470 NEXT Loop
480 !
490 ! - SOFT CLIP -
500 CLIP X_left-.5,X_right+.5,Y_bottom-.5,Y_top+.5
510 FRAME
520 LORG 3
530 MOVE X_left-.5,Y_top+.5
540 LABEL "SOFT CLIP"
550 CSIZE 2
560 FOR I=1 TO 9
570 MOVE 10,Y_top
580 LORG I
590 LABEL I
600 NEXT I
610 RETURN
620 END

TransEra, HTBasic, TAMS, HP, Agilent, Keysight, NI, ines, Microsoft, Windows等記載されている
会社名、製品名は各社の登録商標または商標です

【お問い合わせ先】

アイネット株式会社

　　 E-mailでのお問い合わせ
_/_/_/ Copyright 1998-2023 I2NET Co., Ltd.　AllRights Reserved. _/_/_/